Sentencias o estructuras de Control de Flujo en PSeInt
Las sentencias o estructuras de control de flujo permiten cambiar y controlar la ejecución del programa. Pueden ser condicionales e iterativas o de repetición.
Condicional Simple (Si-Entonces)
Con la estructura de control condicional si-entonces se evalúa una condición, y dependiendo del resultado, verdadero o falso, se ejecuta un bloque de instrucciones u otro. A continuación, verás la sintaxis de la estructura y un ejemplo en el que se piden dos valores, A y B por teclado, se evalúan con la estructura, y según el resultado muestra un texto u otro por pantalla.
// Sintaxis de estructura Si-Entonces
Si (condición) Entonces
(intrucciones)
SiNo
(intrucciones)
FinSi
// Ejemplo
Escribir "Introduce el valor de A: " Sin Saltar;
Leer A
Escribir "Introduce el valor de B: " Sin Saltar;
Leer B
Si (A = B) Entonces
Escribir "A es igual a B";
SiNo
Escribir "A es distinto de B";
FinSi
Selección Múltiple
Con esta estructura también se evalúa una variable, pero se pueden incluir varias opciones, es decir, se pueden tomar varios caminos con la misma estructura, no únicamente dos, como con la estructura si-entonces. Cada opción tiene su bloque de instrucciones a ejecutar. A continuación, puedes ver la sintaxis y un ejemplo en el que podemos escoger entre tres valores numéricos enteros, del 1 al 3, u otro distinto, dependiendo de cual elegimos nos muestra un mensaje por pantalla.
// Sintaxis de estructura Selección Múltiple
Segun (variable) Hacer
(número 1): (instrucciones)
(número 2), (número 3): (instrucciones)
(...)
De Otro Modo: (instrucciones)
FinSegun
// Ejemplo
Definir opcion Como Entero;
Escribir "Elige una opción (1 - 3): " Sin Saltar;
Leer opcion;
Segun opcion Hacer
1:
Escribir "Has elegido la opción 1";
2:
Escribir "Has elegido la opción 2";
3:
Escribir "Has elegido la opción 3";
De Otro Modo:
Escribir "Has elegido una opción distinta";
FinSegun
Bucle o Ciclo Mientras PSeInt
Esta estructura de control repetitiva permite que mientras se cumpla una condición, se ejecute un bloque de instrucciones determinado. A continuación, verás la sintaxis y un ejemplo donde se recorre el array mi_tabla usando la variable i como contador, y el resultado de multiplicar a i por 10 se le asigna a mi_tabla[i], después se muestran los datos introducidos en mi_tabla por pantalla, recorriendo el array usando nuevamente la variable i como contador.
// Sintaxis de estructura Mientras
Mientras (condición) Hacer
(secuencia de acciones)
FinMientras
// Ejemplo
Dimension mi_tabla[10];
Definir i Como Entero;
i <- 1;
Mientras (i <= 10) Hacer
mi_tabla[i] <- i*10;
i <- i+1;
FinMientras
i <- 1;
Mientras (i <= 10) Hacer
Escribir "mi_tabla[" Sin Saltar;
Escribir i Sin Saltar;
Escribir "] = " Sin Saltar;
Escribir i Sin Saltar;
Escribir "x10 = " Sin Saltar;
Escribir mi_tabla[i];
i <- i+1;
FinMientras
Bucle o Ciclo Repetir PSeInt
Esta estructura de control repetitiva es muy parecida a la anterior, pero mientras en la anterior la condición se evalúa al principio de la estructura, en ésta se hace al final. Aquí se repite un bloque de instrucciones hasta que se cumple una condición determinada. A continuación, verás la sintaxis y un ejemplo cuya ejecución da el mismo resultado que el ejemplo anterior, pero utilizando la estructura de control repetir en lugar de la estructura mientras. Como puedes comprobar, en la anterior era mientras que i sea menor o igual que 10 hacer, la secuencia de acciones indicada, y en ésta es repetir, la secuencia de acciones indicada, hasta que i sea mayor que 10.
// Sintaxis de estructura Repetir
Repetir
(secuencia de acciones)
Hasta Que (condición)
// Ejemplo
Dimension mi_tabla[10];
Definir i Como Entero;
i <- 1;
Repetir
mi_tabla[i] <- i*10;
i <- i+1;
Hasta Que(i>10)
i <- 1;
Repetir
Escribir "mi_tabla[" Sin Saltar;
Escribir i Sin Saltar;
Escribir "] = " Sin Saltar;
Escribir i Sin Saltar;
Escribir "x10 = " Sin Saltar;
Escribir mi_tabla[i];
i <- i+1;
Hasta Que(i>10)
Bucle o Ciclo Para PSeInt
Es otra estructura de control repetitiva, pero en este caso, la propia estructura inicializa una variable que se va a usar de contador, además, va sumándole la cantidad paso y por último incluye el valor final que debe tomar la variable para salir del bucle. A continuación, vemos la sintaxis y también el mismo ejemplo que hemos visto con las estructuras mientras y repetir, que como ves, su ejecución da exactamente el mismo resultado.
// Sintaxis de estructura Para
Para (variable_numerica <- valor_inicial) Hasta (valor_final) Con Paso (paso) Hacer
(secuencia_de_acciones)
Fin Para
// Ejemplo
Dimension mi_tabla[10];
Definir i Como Entero;
Para i <- 1 Hasta 10 Con Paso 1 Hacer
mi_tabla[i] <- i*10;
Fin Para
Para i <- 1 Hasta 10 Con Paso 1 Hacer
Escribir "mi_tabla[" Sin Saltar;
Escribir i Sin Saltar;
Escribir "] = " Sin Saltar;
Escribir i Sin Saltar;
Escribir "x10 = " Sin Saltar;
Escribir mi_tabla[i];
Fin Para
